plugins {
    id 'java'
    id 'application'
    id 'maven-publish'
    id 'com.palantir.git-version' version '0.12.3'
}

repositories {

    maven {
        url "https://repo.rudefox.io/repository/maven-public/"
    }
	
    mavenCentral()
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

def isRelease = versionDetails().commitDistance == 0

group 'io.rudefox'
version isRelease ? gitVersion.call() : gitVersion.call() + "-SNAPSHOT"

application {
    mainClassName = 'io.rudefox.cold.RudefoxCold'
}

run {
    standardInput = System.in
}

tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

def junitVersion = "5.6.2"

tasks.withType(Test) {
    useJUnitPlatform()
}

dependencies {
    compile 'io.rudefox:vixen:0.0.2'
    compile 'info.picocli:picocli:4.0.4'
    compile 'com.google.zxing:core:3.4.0'
    testCompile 'com.bjdweck.test:commons-test:0.0.1'
    testCompile "org.junit.jupiter:junit-jupiter-params:$junitVersion"
    testImplementation "org.junit.jupiter:junit-jupiter-api:$junitVersion"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junitVersion"
}

publishing {

    publications {
        distro(MavenPublication) {
            from components.java
            artifact distZip
            artifact distTar
            pom {
                name = 'Rudefox Burrow'
                description = 'Bitcoin offline seed generation and tools'
                url = 'https://rudefox.io/burrow'
                developers {
                    developer {
                        name = 'B.J. Dweck'
                    }
                }
                scm {
                    developerConnection = 'scm:git:https://git.rudefox.io/rudefox/burrow.git'
                    url = 'https://git.rudefox.io/rudefox/burrow/'
                }
            }
        }
    }

    repositories {
        maven {
            name = "rudefox"

            def repoBaseUrl = 'https://repo.rudefox.io/repository'
            url = isRelease ? "${repoBaseUrl}/maven-releases/" : "${repoBaseUrl}/maven-snapshots/"

            credentials {
                username System.getenv("RUDEFOX_MAVEN_USR") ?:
                        (project.hasProperty('rudefox_maven_username') ? project.rudefox_maven_username : "defualt")

                password System.getenv("RUDEFOX_MAVEN_PSW") ?:
                        (project.hasProperty('rudefox_maven_password') ? project.rudefox_maven_password : "defualt")
            }
        }
    }
}